名前空間を利用したデータの受け渡し

CRS - 名前空間

名前空間を利用したデータの受け渡し

Biz/Browser DTでは、名前空間（namespace）を利用してフォーム間でのデータ受け渡しが行えます。

Formなどを定義したアプリケーション画面とは別のCRSファイルに定義した名前空間（namespace）へデータを保持することで、様々な画面から保持したデータを参照することが可能となります。

サンプルでは名前空間（namespace）へ入力値を保持するためのStringオブジェクトを定義し、form1で入力した値をform2で参照しています。

名前空間（namespace）を定義したCRSファイルは、Importで読込みます。Importしたファイルの内容は保持されるため、全CRSファイルにImportを記述する必要はありません。名前空間（namespace）を利用するCRSファイルで一度読み込みを行うだけで利用が可能です。

【form1でTextBoxに値を入力】

【form2に画面遷移】

データの受け渡しはユーザ定義イベントを利用する方法でも可能です。
詳細はユーザ定義イベントを利用したデータの受け渡しを参照してください。

[Gv_c.crs]

namespace Gv_c{
    # 入力値の保持用
    String txt;
}

[form1.crs]

Import "Gv_c.crs";

Form form1 {
    width = 800;
    height = 600;
    bgColor = new Brush("#ffaaffff", Brush.SOLID);

    Textbox Textbox1 {
        x = 32;
        y = 40;
        height = 28;
        # 保持した値をセット
        value = Gv_c.txt;
    }

    Button Button1 {
        x = 32;
        y = 88;
        height = 20;
        title = "form2へ";

        Function OnTouch(e) {
            # Textboxの値を保持
            Gv_c.txt = ^.Textbox1;

            # 次の画面を表示
            form1.delete();
            //.get("form2.crs"); 
        }
    }
}

[form2.crs]

# form1から実行してください

Form form2 {
    width = 800;
    height = 600;
    bgColor = new Brush("#ffffff7f", Brush.SOLID);

    Textbox Textbox1 {
        x = 32;
        y = 32;
        height = 28;

        # 保持した値をセット
        value = Gv_c.txt;
    }

    Button Button1 {
        x = 32;
        y = 88;
        height = 20;
        title = "form1へ戻る";

        Function OnTouch(e) {
            # Textboxの値を保持
            Gv_c.txt = ^.Textbox1;
            # form1へ画面遷移
            form2.delete();
            //.get("form1.crs"); 
        }
    }
}


		Biz-Collections Bizの宝箱トップへ
		Biz/Browser DT・Biz/Designer DT TIPS集トップへ