ドキュメント印刷 PrintStream

/*************************************************************
     サーバ"printserver"から"/xxx"にあるBiz/PrintServerや
     PrintStream Coreのスプールファイルをダウンロードして
     印刷する例
**************************************************************/
PrintStreamDocument PrintStreamDocument1 {
    if ( !$DESIGNTIME ) {
        var down = new httpDownload("http://printserver");
        append(down, "httpDownload1");
                        
        /* httpDownloadのイベントをその親であるPrintStreamDocumentで処理。
        この処理が終了するまでダウンロードは一時停止 */
        Function OnAsyncDownload(e) {

            /* ダウンロードが成功したらそのレスポンスをExtractの引数にする */
            if ( e.response.status == 200 ) {
                var rc = Extract(e.response);

                /* スプールファイルの最後のファイルをExtractしたら
                ダウンロードを終了*/
                if ( rc.status == 0 ) {
                    httpDownload1.Stop();
                    ^.Button1.Active = true;
                    ^.Button2.Active = true;
                }

            /* エラーの場合はダウンロードを終了*/
            } else {
                httpDownload1.Stop();
                ^.Button1.Active = true;
            }
        }
    }
}
    
Button Button1 {
    X = 0;
    Y = 0;
    Width = 80;
    Height = 30;
    Title = "ダウンロード";
    active = true;
    Function OnTouch(e) {
      /* ダウンロードするファイル数がわかっている場合はtoも指定*/
      ^.PrintStreamDocument1.httpDownload1.AddURL("/xxx/00000[001-].pss");
      /* ダウンロードをスタート*/
      ^.PrintStreamDocument1.httpDownload1.Start();
      active = false;
    }
}

Button Button2 {
    X = 80;
    Y = 0;
    Width = 80;
    Height = 30;
    Title = "印刷";
    active = false;
    Function OnTouch(e) {
        /* デフォルトプリンタに全てのページを印刷*/
        ^.PrintStreamDocument1.PrintDocument();
    }
}