カメラ撮影をしたい

画像

２

カメラ撮影をしたい

２

端末のカメラを使用して静止画を撮影したい場合は、CameraCaptureViewクラスを使用します。

ShowCameraメソッドでカメラ起動と設定を行い、Captureメソッドで静止画を撮影します。
ShowCameraメソッドの引数に指定できる設定内容については、以下の通りです。

sourceType	リアカメラ(端末背面側)起動またはフロントカメラ(液晶側)起動を指定します。
extraParams	読取時の細かい設定を指定します。Array型引数のキーに設定名、値に設定値を格納します。詳細についてはオンラインマニュアルをご参照ください。

【　カメラ起動時に指定可能なオプション　】

	・	カメラフラッシュ(LED)の初期状態を指定（点灯 or 消灯）
	・	ズームバーの表示状態を指定（表示 or 非表示）
	・	撮影サイズの指定
		L　低解像度　：解像度のうち最も近いものを自動選択します。
		L　中解像度　：解像度のうち最も近いものを自動選択します。
		L　高解像度　：解像度のうち最も近いものを自動選択します。　(※1)
		L　横352[px] 縦288[px]　(※2)
		L　横640[px] 縦480[px]　(※2)
		L　横1280[px] 縦720[px]　(※2)
		L　横1920[px] 縦1080[px]　(※1)(※2)
		L　横3840[px] 縦2160[px]　(※1)(※2)

		(※1)	環境によっては非常に高負荷となり動作不能になる場合があります。
		(※2)	撮影サイズに対応していない端末では撮影できない可能性があります。

下記のサンプルを実行するとカメラが起動します。
「撮影」ボタンを押下すると、撮影された結果（静止画）がカメラ表示領域下のImageLabelへ
表示されます。もう１度撮影したい場合は「再撮影」ボタンを押下します。

[ サンプルコード ]

Form FrmCamera{
    Width = 333;
    Height = 552;
    Scroll = $NONE;
    BgColor = $WHITE;
    
    /* カメラ撮影領域 */
    CameraCaptureView CameraCaptureView1 {
        Width = 333;
        Height = 252;
    }
    
    /* 撮影ボタン */
    ImageButton btnCapture{
        X = 232;
        Y = 508;
        Width = 100;
        Height = 40;
        Title = "撮影";
        FontSize = 20;
        ButtonStyle = $SURFACE;
        FgColor = $BLACK;
        BgColor = 20;
        
        Function OnTouch( e ) {
            this.Active = $False;
            ^.btnReCapture.Active = $True;
            /* 撮影画像取得 */
            var img = ^.CameraCaptureView1.Capture();
            /* 撮影画像表示 */
            ^.ImageLabel1.SetImage(img);
            /* カメラ停止 */            
            ^.CameraCaptureView1.HideCamera();
        }
    }
    
    /* 再撮影ボタン */
    ImageButton btnReCapture {
        X = 3;
        Y = 508;
        Width = 100;
        Height = 40;
        Title = "再撮影";
        FontSize = 20;
        ButtonStyle = $SURFACE;
        FgColor = $BLACK;
        BgColor = 20;
        Active = $False;
        
        Function OnTouch( e ) {
            ^.btnCapture.Active = $True;
            /* 再撮影ボタン非表示 */
            this.Active = $False;
            /* 0.1秒後にカメラ起動 */
            ^.SetTimer(0.1,true);
        }
    }
    
    ImageLabel ImageLabel1 {
        Y = 253;
        Width = 333;
        Height = 243;
        Resize = $KEEPRATIO;
        ImageWidth = this.Width;
        ImageHeight = this.Height;
    }
    
    Function OnTimer(e){
        try{
            var extraParams = new Array();
            /* フラッシュ初期消灯 */
            extraParams["CAMERA_FLASH"] = $False;
            /* 高解像度 */
            extraParams["CAMERA_SIZE"] = Runtime.CAMERA_SIZE_HIGH;
            /* ズームバー表示 */
            extraParams["SHOW_ZOOMBAR"] = $True;
            /* カメラ起動 */
            CameraCaptureView1.ShowCamera(Runtime.SourceTypeRearCamera,extraParams);
        }catch (e) {
            //.MessageBox(e.message);
        }
    }

    if ( !$DESIGNTIME ) {
        Width = //.Width;
        Height = //.Height;
        HorizontalScale &= //.Width / 333;
        VerticalScale &= //.Height / 552;
        /* 0.1秒後にカメラ起動 */
        SetTimer(0.1,true);
    }
}

管理番号：PctHt_002


		Biz-Collections Bizの宝箱トップへ
		Biz/Browser HT・Biz/Browser SmartDevice・Biz/Browser AI TIPS集トップへ