動画ファイルを再生したい

ファイル

２

動画ファイルを再生したい

２

MediaPlayerクラスでは、Biz/Browser上で動画ファイル（メディア）を再生することが可能です。

再生したい動画ファイルはLoadFromFileメソッドまたはLoadFromURLメソッドで読込みます。
端末内の動画ファイルを指定する場合はLoadFromFileメソッド、URLで指定する場合はLoadFromURLメソッドをご利用ください。

動画の再生はStartメソッドを使用します。Parseメソッドで動画を一時停止した場合、停止した状態から再生を再開します。動画の再生を停止する場合はStopメソッドを使用します。
また、動画をループ再生したり、任意の位置から再生することも可能です。ループ指定を行う場合はIsLoopingプロパティ、再生位置を指定する場合は、Seekメソッドを利用します。

[ サンプルコード ]

Form sample1 {
  Width = 529;
  Height = 543;

  /* 一時停止の判定用フラグ */
  Number flg = 0;

  MediaPlayer mp {
      Width = 482;
      Height = 248;
      X = 22;
      Y = 9;
  }
  
  OptionButton OptionButton1 {
      X = 276;
      Y = 357;
      Width = 228;
      Height = 47;
      Border = $TRUE;
      
      OptionItem OptionItem1[2] {
          Height = 28;
          Layout = $HORIZONTAL;
          Width = 111;
      }
      
      OptionItem1[0].Title = "ループ再生あり";
      OptionItem1[1].Title = "ループ再生なし";
  }
  
  NumberEdit NumberEdit1 {
      X = 276;
      Y = 417;
      Width = 85;
      Height = 31;
  }

  Label Label1 {
      X = 22;
      Y = 359;
      Width = 255;
      Height = 40;
      BgColor = $FFFFFF;
      Value = "ループ再生の有無";
  }
  
  Label Label2 {
      X = 22;
      Y = 417;
      Width = 255;
      Height = 32;
      BgColor = $FFFFFF;
      Value = "動画の再生位置（秒単位で指定）";
      HorizontalAlign = $LEFT;
      VerticalAlign = $CENTER;
  }

  Button Button1 {
      X = 21;
      Y = 277;
      Width = 196;
      Height = 44;
      Title = "再生する動画ファイルのロード";
      
      Function onTouch(e) {
          /* 動画ファイルのロード */
          /* 配置先のURLパス、ご利用のファイル名に修正してお試しください */
          var filepass = "http://localhost/sample1.mp4";
          try {
              ^.mp.loadFromUrl(filepass);
          } catch(e) {
              //.MessageBox(e.Message);
          }
      }
  }

  Button Button2 {
      X = 22;
      Y = 469;
      Width = 140;
      Height = 44;
      Title = "再生開始";
      
      Function onTouch(e) {
          try {
              /* ループ再生の設定 */
              if(^.OptionButton1.Value == 0){
                  ^.mp.IsLooping = $TRUE;
              }else{
                  ^.mp.IsLooping = $FALSE;
              }
              
              /* 再生位置を設定 */
              var s = ^.NumberEdit1.Value;

              if(^.flg == 0){
                /* 一時停止の場合は無視 */
                ^.mp.Seek(s);
              }else{
                /* 判定用フラグ初期化 */
                ^.flg = 0;
              }
              
              /* 動画ファイルを再生する */
              ^.mp.Start();
          } catch(e) {
              //.MessageBox(e.Message);
          }
      }
  }

  Button Button3 {
      X = 181;
      Y = 469;
      Width = 140;
      Height = 44;
      Title = "一時停止";
      
      Function onTouch(e) {
          try {
              /* 動画ファイルを一時停止する */
              ^.mp.Pause();
              /* 判定用フラグ更新 */
              ^.flg = 1;
          } catch(e) {
              //.MessageBox(e.Message);
          }
      }
  }
  
  Button Button4 {
      X = 340;
      Y = 469;
      Width = 140;
      Height = 44;
      Title = "再生停止";
      
      Function onTouch(e) {
          try {
              /* 動画ファイルを停止する */
              ^.mp.Stop();
          } catch(e) {
              //.MessageBox(e.Message);
          }
      }
  }
}

【注意事項】

再生可能なフォーマット形式は端末やOSのバージョンによって異なります。

管理番号：FileHt_002


		Biz-Collections Bizの宝箱トップへ
		Biz/Browser HT・Biz/Browser SmartDevice・Biz/Browser AI TIPS集トップへ