セルに先頭ゼロを表示させる際の注意点

Spread - デザイン

セルに先頭ゼロを表示させる際の注意点

セルのvalue値に数字を設定し、先頭ゼロを表示させるにはSubType(データ型)を文字型の「SpreadStyleText:String」に指定します。

SubType(データ型)を指定する他、セルのスタイルを設定する際の注意点として、maxColumnsプロパティを予め設定する必要があります。

スタイルの設定は、既に存在する列に対して有効になります。
maxColumnsプロパティを設定していなければ、列が存在しないためスタイル設定は反映されません。この場合、セルは数値扱いとなり実行結果②のように先頭ゼロが表示されなくなります。

【実行結果①】

【実行結果②】

Form form1 {
	width = 800;
	height = 600;
	
	CsvDocument sp_doc;
	/* データをsp_docにロード */
	sp_doc << CSV{
	00001,田中太郎,たなかたろう,0105,営業部
	00002,鈴木一郎,すずきいちろう,0101,開発部
	00003,佐藤次郎,さとうじろう,0200,総務部
	00004,山田花子,やまだはなこ,0202,経理部};
					
	Spread spread1 {
		x = 24;
		y = 40;
		width = 424;
		height = 191;
		maxRows = ^.sp_doc.rows;
		/* スタイル設定にはmaxColumnsプロパティの記述が必要 */
		maxColumns = ^.sp_doc.columns;
	
		/* 先頭ゼロを表示するため、SpreadStyleTextを定義(SubType:String) */
		var sString = new SpreadStyleText:String;
		/* 背景色設定 */
		sString.bgColor = Color.CYAN;
		/* AとD列にstyleを設定 */
		columns("A").style = sString;
		columns("D").style = sString;
	}

	Spread spread2 {
		x = 24;
		y = 280;
		width = 424;
		height = 191;

		/* 先頭ゼロを表示するため、SpreadStyleTextを定義(SubType:String) */
		var sString = new SpreadStyleText:String;
		/* 背景色設定 */
		sString.bgColor = Color.CYAN;
		/* AとD列にstyleを設定 */
		columns("A").style = sString;
		columns("D").style = sString;
	}

	Label label1 {
		x = 24;
		y = 16;
		width = 424;
		height = 24;
		value = "文字列型設定あり、maxColumnsプロパティの設定あり";
		bgColor = new Brush("#ffffffff", Brush.SOLID);
		verticalAlign = ALIGN_MIDDLE;
	}

	Label label2 {
		x = 24;
		y = 256;
		width = 424;
		height = 24;
		value = "文字列型設定あり、maxColumnsプロパティの設定なし";
		bgColor = new Brush("#ffffffff", Brush.SOLID);
		verticalAlign = ALIGN_MIDDLE;
	}
								
	if (!Application.DESIGNTIME) {
		/* オペレータでデータをSpreadにロード */
		spread1 << sp_doc;
		spread2 << sp_doc;
	}
}


		Biz-Collections Bizの宝箱トップへ
		Biz/Browser DT・Biz/Designer DT TIPS集トップへ