帳票のプレビュー（PrintStream Coreとの連携）

帳票 - プレビュー

帳票のプレビュー（PrintStream Coreとの連携）

Biz/Browser DT ver1.2.0からWeb帳票ツール「PrintStream Core」で作成した帳票（PSSファイル）を画面上でプレビュー・印刷できるようになりました。

PrintStreamDocumentクラスを使ってサーバから帳票（PSSファイル）をダウンロードし、PrintPreviewクラスのオブジェクトにロードすると簡単にプレビュー画面を実装する事が可能です。

[ 画面イメージ ]

Form form1 {
	width = 1193;
	height = 721;
	
	PrintStreamDocument pssDoc {
		function onExtractFinished(e) {
			//.messageBox("帳票（PSSファイル）の取得が終了しました（"+str(status)+"）");
		}
	}

	PrintPreview preview {
		x = 8;
		y = 72;
		width = 1168;
		height = 632;
	}

	TextBox textUrl {
		x = 8;
		y = 48;
		width = 448;
		height = 24;
#		PSSファイルはご利用のサーバのファイルを指定してください
		value = "http://server.com/pss/";
	}

	Button buttonGet {
		x = 464;
		y = 48;
		width = 216;
		height = 24;
		title = "帳票（PSSファイル）プレビュー";
		function onTouch(e) {
#			PrintPreviewの初期化
			^.preview.clearPages();
			
#			ファイルダウンロード失敗時のリトライ回数
			var retryCount = 3;
#			ファイルダウンロード失敗時、次のダウンロード開始待ち時間
			var waitTime = 4.0;
#			ダウンロード失敗が続く場合の、待ち時間の増加係数
			var waitScale = 2.0;
#			PSSファイルの取得
			^.pssDoc.get(^.textUrl.value, retryCount, waitTime, waitScale);
#			取得したファイルを表示
			^.preview.document = ^.pssDoc;
		}
	}
	Label label1 {
		x = 8;
		y = 16;
		width = 376;
		height = 24;
		value = "帳票（PSSファイル）のダウンロードURL";
	}
}


		Biz-Collections Bizの宝箱トップへ
		Biz/Browser DT・Biz/Designer DT TIPS集トップへ