帳票のプレビュー（クライアント帳票印刷）

帳票 - プレビュー

帳票のプレビュー（クライアント帳票印刷）

Biz/Browser DT ver1.2.0からクライアント帳票印刷が可能となりました。

CRSスクリプトで帳票レイアウトを作成し、実行する事で画面上での帳票プレビューや
プリンターへの出力ができます。
帳票のレイアウトは、PrintFormクラスを利用して作成し、PrintPreviewクラスでプレビューします。
帳票の各項目は、以下のクラスを組み合わせて表現します。

・	TextField			・・・	PrintFormに文字ラベルを表示
・	ImageField			・・・	PrintFormに画像を表示
・	PrintRegion			・・・	PrintFormに表形式のデータを表示
	－	PrintHeader		・・・	PrintRegionの見出し行
		－	HeaderField	・・・	PrintRegionによる表の見出しセル
	－	PrintRecord		・・・	PrintRegionのデータ行
					PrintRecordオブジェクトの配下に、TextFieldやImageFieldオブジェクトを配置してセルを表現します。

[ 画面イメージ ]

[　プレビュー画面　]

Form MainForm {
    width = 1001;
    height = 689;
    
    Button button1 {
        x = 224;
        y = 16;
        width = 448;
        height = 40;
        title = "帳票プレビュー";
        font = new Font("MS UI Gothic", 20);
        function onTouch(e) {
#            レイアウトが定義されたPrintFormを取得
            ^.get("Printform1.crs");
#            PrintPreviewの初期化
            ^.printpreview1.clearPages();
#            印刷データ生成処理を実行し、PrintPreviewへ表示
            ^.printpreview1.document = ^.printform1.printDocument();
        }
    }
    PrintPreview printpreview1 {
        x = 9;
        y = 64;
        width = 975;
        height = 584;
        zoomFactor = 1;
    }
    if (!Application.DESIGNTIME) {
        var fw = //.getFrameWindow();
        fw.width = width;
        fw.height= height;
        fw.statusBar = false;
        fw.resize = false;
    }
}

[　帳票レイアウト　]

PrintForm printform1 {
	width = 800;
	height = 1043;
	visible = false;
	
	var h_bg= new Color(0xffc0c0c0);
	var h_fk = new Font("MS UI Gothic", 20, true, false, false, false);
	
	TextField textfield1 {
		x = 79;
		y = 31;
		width = 648;
		height = 64;
		value = "出席者名簿";
		border = BORDER_PLANE;
		horizontalAlign = ALIGN_CENTER;
		verticalAlign = ALIGN_MIDDLE;
		font = new Font("MS UI Gothic", 22, true, false, false, false);
	}
	PrintRegion printregion1 {
		x = 79;
		y = 127;
		width = 648;
		height = 886;
		border = BORDER_PLANE;
		
		PrintHeader printheader1 {
			width = 648;
			height = 48;
			bgColor = h_bg;
			HeaderField headerfield1 {
				width = 174;
				height = 48;
				title = "氏名";
				verticalAlign = ALIGN_MIDDLE;
				horizontalAlign = ALIGN_CENTER;
				font = h_fk;
			}
			
			HeaderField headerfield2 {
				x = 130;
				y = 0;
				width = 68;
				height = 48;
				title = "年齢";
				verticalAlign = ALIGN_MIDDLE;
				horizontalAlign = ALIGN_CENTER;
				font = h_fk;
			}
			
			HeaderField headerfield3 {
				x = 245;
				y = 0;
				width = 241;
				height = 48;
				title = "住所";
				verticalAlign = ALIGN_MIDDLE;
				horizontalAlign = ALIGN_CENTER;
				font = h_fk;
			}
			HeaderField headerfield4 {
				x = 337;
				y = 0;
				width = 158;
				height = 48;
				title = "電話番号";
				verticalAlign = ALIGN_MIDDLE;
				horizontalAlign = ALIGN_CENTER;
				font = h_fk;
			}
		}
		PrintRecord printrecord1[]{
			x = 16;
			y = 72;
			width = 631;
			height = 48;
			TextField textfield1 {
				verticalAlign = ALIGN_MIDDLE;
				font = h_fk;
			}
			TextField textfield2 {
				verticalAlign = ALIGN_MIDDLE;
				font = h_fk;
				horizontalAlign = ALIGN_CENTER;
			}
			TextField textfield3 {
				verticalAlign = ALIGN_MIDDLE;
				font = h_fk;
			}
			TextField textfield4 {
				verticalAlign = ALIGN_MIDDLE;
				font = h_fk;
			}
		}
	}

	if (!Application.DESIGNTIME) {
		# ここに初期化処理を記述してください。
		printform1.printregion1.printrecord1 << csv(氏名,年齢,住所,電話番号) {
			伊藤博文,44,山口県○○○,xxx-xx-xxx
			黒田清隆,47,鹿児島県○○○,xxx-xx-xxx
			山縣有朋,51,山口県○○○,xxx-xx-xxx
			松方正義,56,鹿児島県○○○,xxx-xx-xxx
			大隈重信,60,佐賀県○○○,xxx-xx-xxx
			桂太郎,53,山口県○○○,xxx-xx-xxx
			西園寺公望,56,京都府○○○,xxx-xx-xxx
			山本權兵衞,60,鹿児島県○○○,xxx-xx-xxx
			寺内正毅,64,山口県○○○,xxx-xx-xxx
			原敬,62,岩手県○○○,1xxx-xx-xxx
			高橋是清,67,東京都〇〇〇,xxx-xx-xxx
			加藤友三郎,61,広島県〇〇〇,xxx-xx-xxx
			清浦奎吾,73,熊本県〇〇〇,xxx-xx-xxx
			加藤高明,64,愛知県〇〇〇,xxx-xx-xxx
			若槻禮次郎,59,島根県〇〇〇,xxx-xx-xxx
			田中義一,63,山口県〇〇〇,xxx-xx-xxx
			濱口雄幸,59,高知県〇〇〇,xxx-xx-xxx
			犬養毅,76,岡山県〇〇〇,xxx-xx-xxx
			齋藤實,73,岩手県〇〇〇,xxx-xx-xxx
			岡田啓介,66,福井県〇〇〇,xxx-xx-xxx
		};
	}
}


		Biz-Collections Bizの宝箱トップへ
		Biz/Browser DT・Biz/Designer DT TIPS集トップへ