画面キャプチャを画像ファイル（ビットマップ、JPG、PNG）で保存したい

ファイル - 保存

画面キャプチャを画像ファイル（ビットマップ、JPG、PNG）で保存したい

Biz/Browser DTでは、DisplayObjectクラスにgrabメソッドが追加されました。
grabメソッドを実行することで、メソッドを実行したオブジェクトの表示状態を
Imageオブジェクトとして取得することができます。
取得したImageオブジェクトのsaveメソッドを用いることで、画面キャプチャを画像ファイルで保存することができます。
grabメソッドは、実行したオブジェクトと、その下位に位置するオブジェクトを画像に収めます。

【実行結果①】

【実行結果②】

Form form1 {
    x = 0;
    y = 0;
    width = 800;
    height = 600;
    bgColor = "white";
 
    label lb1 {
        x = 306;
        y = 41;
        width = 292;
        height = 248;
        value = "Labelオブジェクト";
        Font = new Font("Meiryo UI", 15, $True, $False, $False, $False);
        bgColor = new Color(0,0,255,127);
    }
 
    Label lb2 {
        x = 131;
        y = 103;
        width = 332;
        height = 302;
        bgColor = "red";
        value = "Labelオブジェクト";
        Font = new Font("Meiryo UI", 15, $True, $False, $False, $False);
        opacity = 0.5;
        tabindex = 5;
    }

    label lb3 {
        x = 339;
        y = 141;
        width = 347;
        height = 327;
        value = "Labelオブジェクト";
        Font = new Font("Meiryo UI", 15, $True, $False, $False, $False);
        bgColor = new Color(0,255,0,127);
    }
 
    Button btn {
        x = 38;
        y = 463;
        width = 200;
        height = 100;
        title = "grabメソッドでForm画面を保存";
  
        Function OnTouch(e) {
  
            /* writerオブジェクトを生成 */
            var fs = new FileSystem(FileSystem.PUBLIC_ROOT);
            var fw = fs.open("capcha.jpg", FileSystem.OPEN_WRITE);
   
            /* form1(+下位に位置するオブジェクト)をキャプチャ */
            var img = form1.grab();
   
            /* 第一引数にwriterオブジェクト、第二引数に画像のフォーマットを指定して保存 */
            /* フォーマットは、PNG,JPEG,BMPから選ぶことができます。 */
            img.save(fw, Image.JPEG);
   
            /* ファイルをクローズ */
            fw.close();
        }
    }
 
    Button btn2 {
        x = 138;
        y = 302;
        width = 181;
        height = 83;
        title = "grabメソッドで赤ラベル画面を保存";
  
        Function OnTouch(e) {
   
            /* writerオブジェクトを生成 */
            var fs = new FileSystem(FileSystem.PUBLIC_ROOT);
            var fw = fs.open("capcha2.jpg", FileSystem.OPEN_WRITE);
   
            /* lb2をキャプチャ */
            var img = form1.lb2.grab();
   
            /* 第一引数にwriterオブジェクト、第二引数に画像のフォーマットを指定して保存 */
            /* フォーマットは、PNG,JPEG,BMPから選ぶことができます。 */
            img.save(fw, Image.JPEG);
   
            /* ファイルをクローズ */
            fw.close();
        }
    }
}


		Biz-Collections Bizの宝箱トップへ
		Biz/Browser DT・Biz/Designer DT TIPS集トップへ