名前空間の指定

CRS - 名前空間

名前空間の指定

Biz/Browser DTでは、名前空間（namespace）という機能が新しく追加されました。
従来のpackageクラスと同じで共通部品を定義するためのものですが、記述方法が
packageクラスと異なります。

namespace記述例　(ファイル名：MyPackage.crs)

namespace MyPackage {

    /* クラス(Button) */
    class MyButton extends Button {
        title = "MyButton";
        function OnTouch(e) {
            //.messageBox("Hello");
        }
    }
    
    /* クラス(TextBox) */
    class MyTextBox extends TextBox {
        value = "MyTextBox";
        bgColor = Color.YELLOW;
    }

    /* ファンクション */
    function MyFunction(moji) {
        //.messageBox(moji);
    }

    /* オブジェクト変数 */
    String MyData = "sample";
}

Formで作成された画面で名前空間内のクラスやファンクションを使用する場合、名前空間名で修飾した形式で定義します。例えば、上記例のMyButtonクラスを使用する場合は以下のように記述します。

MyPackage::MyButton btn {
　　x = 24
　　y = 32;
　　width = 120;
　　height = 30;
}

上記例のMyFunction関数を使用する場合は以下のように記述します。

MyPackage.MyFunction("MyFunction");

名前空間も、従来のpackageクラスと使い方は同じです。画面(Form)とは別のCRSファイルとして用意しておき、ライブラリのようにimportして使用します。

Form記述例　(ファイル名：form1.crs)

import "MyPackage.crs";

Form form1 {
    width = 800;
    height = 600;
    
    /* 名前空間のMyButtonクラス */
    MyPackage::MyButton btn {
        x = 24;
        y = 32;
        width = 120;
        height = 30;
    }
    
    /* 名前空間のMyTextBoxクラス */
    MyPackage::MyTextBox txt {
        x = 24;
        y = 72;
        width = 216;
        height = 32;
    }
    
    /* 通常のButtonクラス */
    Button btn2 {
        x = 160;
        y = 32;
        width = 120;
        height = 30;
        title = "ボタン";
        function onTouch(e) {
            /* 名前空間のファンクションを呼び出す */
            MyPackage.MyFunction("MyFunction");
        }
    }
    
    /* 通常のTextBoxクラス */
    TextBox txt2 {
        x = 24;
        y = 116;
        width = 216;
        height = 32;
        /* 名前空間のオブジェクト変数をセット */
        value = MyPackage.MyData;
    }
}

名前空間名で修飾した指定方法はクラス名の衝突を避けられるメリットがあります。
ただ、同名のクラスが他に存在しない場合、全てのクラス名で名前空間を修飾するのが煩わしくなる場合があります。
そのような場合は、using指定を行うことにより、修飾なしのクラス名のみで名前空間内のクラスを使用することが可能です。

Form記述例　(ファイル名：form2.crs)

import "MyPackage.crs";
# MyPackage内の全てのクラスが修飾なしでアクセス可能
using namespace MyPackage;

Form form2 {
	width = 800;
	height = 600;
	# 修飾なしでのMyButtonクラスを指定
	MyButton btn {
		x = 24;
		y = 32;
		width = 120;
		height = 30;
	}
}

なお、Biz/Browser DTでもpackageクラスで共通部品を定義することは可能です。
namespaceではなくpackageクラスを使用した場合、using指定を行った場合と同じ動作となります。
(using namespace MyPackageが暗黙的に呼ばれます)


		Biz-Collections Bizの宝箱トップへ
		Biz/Browser DT・Biz/Designer DT TIPS集トップへ