配列を使いたい（Arrayクラス・Mapクラス）

CRS - 配列

配列を使いたい（Arrayクラス・Mapクラス）

Biz/Browser DTの配列クラスとして、動的配列を保持するArrayクラスと連想配列を保持するMapクラスの2種類があります。

配列の基本的な使用方法は同じですが、添え字に使用できる文字種が異なります。
Arrayクラスは数字のみ、Mapクラスは任意の文字列が使用できます。

１．Arrayクラス

Form Array {
    x = 0;
    y = 0;
    width = 400;
    height = 597;

    # 配列
    Array arr1;
    arr1[0] = "ABC";
    arr1[1] = "あいう";
    arr1[2] = "123";
    
    Label label1 {
        x = 20;
        y = 33;
        width = 322;
        height = 31;
        value = "配列の内容：ABC/あいう/123";
        horizontalAlign = ALIGN_CENTER;
        verticalAlign = ALIGN_MIDDLE;
        bgColor = Color.WHITE;
        border = true;
    }
    TextBox textbox1 {
        x = 51;
        y = 131;
        width = 290;
        height = 27;
    }
    
    TextBox textbox2 {
        x = 51;
        y = 165;
        width = 290;
        height = 27;
    }
    EditBox editbox1 {
        x = 14;
        y = 200;
        width = 326;
        height = 157;
    }
    Button button1 {
        x = 185;
        y = 82;
        width = 155;
        height = 35;
        title = "要素数・value値の取得";
        function onTouch(e) {
            # Arrayの配列要素の数
            var len = "要素数：" + str(^.arr1.length);
            # 取得した内容をTextBoxに表示
            ^.textbox1.value = len;
            # Arrayのvalue値
            var arrdata1 = "value値：" + ^.arr1.value;
            # 取得した内容をTextBoxに表示
            ^.textbox2.value = arrdata1;
            
            var i;
            var arrdata2;
            
            # 取得した各要素のvalue値をEditBoxに表示
            for (i in ^.arr1) {
                ^.editbox1 += "添え字：" +str(i)  +" value値：" +^.arr1[i] + "\r\n";
            }
        }
    }
}

２．Mapクラス

Form Map {
    x = 0;
    y = 0;
    width = 400;
    height = 597;

    # 配列
    Map mp;
    mp["data1"] = "データ１";
    mp["data2"] = "データ２";
    mp["data3"] = "データ３";
    
    Label label1 {
        x = 20;
        y = 33;
        width = 322;
        height = 31;
        value = "配列の内容：データ１/データ２/データ３";
        horizontalAlign = ALIGN_CENTER;
        verticalAlign = ALIGN_MIDDLE;
        bgColor = Color.WHITE;
        border = true;
    }
    TextBox textbox1 {
        x = 51;
        y = 131;
        width = 290;
        height = 27;
    }
    EditBox editbox1 {
        x = 14;
        y = 167;
        width = 326;
        height = 157;
    }
    Button button1 {
        x = 185;
        y = 82;
        width = 155;
        height = 35;
        title = "要素数・値の取得";
        function onTouch(e) {
            # Mapの配列要素の数
            var len = "要素数：" + str(^.mp.length);
            # 取得した内容をTextBoxに表示
            ^.textbox1.value = len;

            var i;
            
            # 取得した各要素の値をEditBoxに表示
            # ※for-in文で取り出される順序は不定です
            for (i in ^.mp) {
                ^.editbox1 += "添え字（キー）：" +str(i)  +" 値：" +^.mp[i] + "\r\n";
            }
        }
    }
}


		Biz-Collections Bizの宝箱トップへ
		Biz/Browser DT・Biz/Designer DT TIPS集トップへ