オブジェクト間の自動再計算

"//"から始まる階層構造に含まれるオブジェクトは、オブジェクト間を参照演算子(&=)で接続することにより、演算子の右辺の値の変化に連動して自動的に左辺の値を再計算する事ができます。

参照演算子の使い方

例 ウィンドウのサイズにあわせてボタンの表示位置を調整

Form Form1 {
    Width = 500;
    Height = 400;
    Button Button1 {
        X &= Form1.Width / 5;
        Y &= Form1.Height / 5;
        Width &= (Form1.Width / 5) * 3;
        Height &= (Form1.Height / 5) * 3;
    }
}

"//"（Rootオブジェクト）の直下にあるForm1は、ウィンドウのサイズ変更に自動的に追従し、WidthとHeightプロパティが変化します。この例では、Button1のX、Y、Width、Heightを&=演算子でForm1のWidthとHeightに関連させているので、ウィンドウのサイズ変更に追従して、Button1の表示位置と大きさが変化します。

例 TextBoxのエラー表示

Form Form1 {
    Width = 500;
    Height = 400;
    TextBox Text1 {
        X = 10;
        Y = 10;
        Width = 100;
        Height = 30;
        BgColor &= (Err == 0 ? $STD : $RED);
        Number Err {
            Value = 0;
        }
    }
    Button Button1 {
        X = 10;
        Y = 50;
        Width = 100;
        Height = 30;
        Function OnTouch(e) {
            if (Form1.Text1 == "") {
                Form1.Text1.Err = 1;
            } else {
                Form1.Text1.Err = 0;
            }
        }
    }
}

この例では、Button1を押したときに反応するイベントハンドラにより、Text1の内容が空であればForm1.Text1.Errに1を、空でなければ0を設定しています。

Text1の背景色は &= 演算子によりErrに関連しているので、Errに1がセットされたときに、赤く反応します。

このように参照演算子 &= を利用することで、スクリプトを「背景を赤くする」という処理ではなく、「エラーをセットする」というより本質的な処理で記述することができるようになります。

参照演算子の制約

オブジェクトツリー内でのみ利用できます

参照演算子は"//"（Rootオブジェクト）を頂点とするオブジェクトツリーに含まれるオブジェクトに対してのみ利用することができます。参照演算子の左辺、右辺ともvar変数で参照している無名のオブジェクトや、グローバル名前空間にロードされたユーザオブジェクトを含むことはできません。

右辺に更新動作を伴う式や関数を記述することはできません

参照演算子の右辺に更新操作を伴う式を記述すると、関連性の依存関係が非常に複雑となるため、CRSではサポートしていません。更新操作を伴う演算子とは++や--演算子などが該当します。

右辺にユーザ定義関数を記述することはできません

参照演算子の右辺にFunctionで定義するユーザ定義関数を記述することはできません。

依存関係の解析は、右辺に出現するシンボルにより行われます

参照演算子の右辺には、更新動作を伴わないグローバル関数やメソッドを記述することができます。CRSインタプリタは右辺に出現するシンボル（オブジェクト名やプロパティ名）を頼りに依存関係を管理しているので、メソッドの呼び出しにより２次的に変化する値を右辺に記述した場合、再計算が実行されないことがあります。