API version 1

- ‐

RW

boolean

autoClose

ポップアップ表示されたウィンドウを自動的に閉じるかどうかを指定します。

trueを指定した場合は、ステップがmaximumプロパティで指定した最大値に達すると、ポップアップ表示されたウィンドウを自動的に閉じます。

falseを指定した場合には、ウィンドウは自動的には閉じません。閉じるにはpopupCloseメソッドを呼び出します。

初期値はfalseです。

関連項目

maximumプロパティ

popup、popupCloseメソッド

使用例 CRSダウンロード

Form ProgressPopup_autoClose {
   x = 0;
   y = 0;
   width = 800;
   height = 185;


   ProgressPopup progressPopup1 {

           autoClose = true;
           cancelCaption = "閉じる";
           message = "テストメッセージ";

           minimum = 0;
           maximum = 100;

           function onTimer(e) {
                   print("ProgressPopup オブジェクトに Timer イベントが発生しました。");
           }
   }

   Button buttonAutoClose {
           x = 8;
           y = 8;
           width = 224;
           height = 24;
           title = "Popup&AutoStep&AutoClose";

           function onTouch(e) {
                   print("ProgressPopup ウィンドウを表示後、2秒後に autoStep を開始し、プログレスバーが右端に到達したら自動的に閉じます。");
                   ^.progressPopup1.message = "2秒後に autoStep を開始し、プログレスバーが右端に到達したら自動的に閉じます。";
                   ^.progressPopup1.value = 0;

                   # プログレスバーが右端に到達したら自動的に閉じるように設定します。
                   ^.progressPopup1.autoClose = true;

                   ^.progressPopup1.popup(true, true);
                   setTimer(2, true);
           }

           function onTimer(e) {
                   print("Button オブジェクトに Timerイベントが発生しました。");
                   if (!^.progressPopup1.visible) {
                           print("ProgressPopup ウィンドウが閉じられています。");
                           return;
                   }
                   print("autoStep を開始します。プログレスバーが右端に到達したら自動的に閉じます。");
                   ^.progressPopup1.autoStep(3.0, true);
           }
   }
}